Consist of a lower and upper body combination with eye-end mounts at the top and bottom. 200 mm-long helical spring (44 mm OD, and wire diameter of 6 mm) captured between upper and lower seats; Internal piston rod running through the spring. Integrated bump-stop beneath the upper seat to limit compression stroke. The assembly provides adjustable ride height and damping when installed between chassis and wheel hub.

// Coilover Assembly
// Consist of a lower and upper body combination with eye-end mounts at the top and bottom. 200 mm-long helical spring (44 mm OD, and wire diameter of 6 mm) captured between upper and lower seats; Internal piston rod running through the spring. Integrated bump-stop beneath the upper seat to limit compression stroke. The assembly provides adjustable ride height and damping when installed between chassis and wheel hub.
// Categories: Automotive

// Set units
@settings(defaultLengthUnit = mm)

import "coilover-bottom.kcl" as coiloverBottom
import "spring.kcl" as coiloverSpring
import "coilover-top.kcl" as coiloverTop

// Place the Bottom Coilover Part
coiloverBottom

// Place the Coilover Spring
coiloverSpring

// Place the Top Coilover Part
coiloverTop
  |> translate(x = 0, y = 0.0, z = 200)


// Coilover Bottom
// Part consists of a 70 mm diameter retainer plate with a cylindrical lower mount body below it, and a eye-end mount (or hole) at the bottom. Above the retainer plate, there is a cylindrical damper body with a hole through its length that allows a piston shaft to pass through it when included in the coilover assembly.

// Set units
@settings(defaultLengthUnit = mm, kclVersion = 1.0)

// Import parameters
import retainerPlateDia, retainerPlateLength, baseSeatingDia, baseSeatingLength, lowerMountDia, damperBodyLength, lowerMountLength, eyeEndMountOuterDia, eyeEndMountLength, eyeEndMountHoleDia, eyeEndMountThickness, eyeEndMountFillet, damperBodyDia, pistonShaftHoleDia, lengthBelowRetainerPlate, lowerMountOverallLength, pointOffset from "parameters.kcl"

// Retainer Plate
retainerPlateSketch = startSketchOn(XY)
retainerPlateProfile = circle(
  retainerPlateSketch,
  center = [0, 0],
  radius = retainerPlateDia / 2,
  tag = $seg01,
)
retainerPlateExtrude = extrude(retainerPlateProfile, length = retainerPlateLength, tagStart = $capStart001)
  |> chamfer(
       length = 3.7,
       tags = [
         getCommonEdge(faces = [seg01, capStart001])
       ],
     )

// Base seating just below the retainer plate
baseSeatingSketch = startSketchOn(retainerPlateExtrude, face = START)
baseSeatingProfile = circle(baseSeatingSketch, center = [0.0, 0.0], radius = baseSeatingDia / 2)
baseSeatingExtrude = extrude(baseSeatingProfile, length = baseSeatingLength)

// Lower Mount
lowerMountSketch = startSketchOn(baseSeatingExtrude, face = END)
lowerMountProfile = circle(
  lowerMountSketch,
  center = [0, 0],
  radius = lowerMountDia / 2,
  tag = $seg02,
)
lowerMountExtrude = extrude(lowerMountProfile, length = lowerMountLength, tagEnd = $capEnd001)
  |> chamfer(
       length = 3,
       tags = [
         getCommonEdge(faces = [seg02, capEnd001])
       ],
     )

// Eye End for Lower Mount
eyeEndSketch = startSketchOn(lowerMountExtrude, face = END)
eyeEndProfile = circle(
  eyeEndSketch,
  center = [0, 0],
  radius = eyeEndMountOuterDia / 2,
  tag = $seg04,
)
eyeEndExtrude = extrude(eyeEndProfile, length = eyeEndMountLength, tagEnd = $capEnd002)
  |> fillet(
       radius = eyeEndMountOuterDia / 2 - 0.01,
       tags = [
         getCommonEdge(faces = [seg04, capEnd002])
       ],
     )
  |> fillet(
       radius = 3,
       tags = [
         getCommonEdge(faces = [capEnd001, seg04])
       ],
     )

// Eye End Outer Profile for Lower Mount
eyeEndOuterSketch = startSketchOn(YZ)

eyeEndOuterProfile = startProfile(
       eyeEndOuterSketch,
       at = [
         eyeEndMountThickness / 2 + eyeEndMountFillet + pointOffset,
         -lengthBelowRetainerPlate + 25
       ],
     )
  |> xLine(length = -pointOffset)
  |> tangentialArc(radius = eyeEndMountFillet, angle = 90)
  |> yLine(length = -22)
  |> xLine(length = -eyeEndMountThickness)
  |> yLine(length = 22)
  |> tangentialArc(radius = eyeEndMountFillet, angle = 90)
  |> xLine(length = -pointOffset)
  |> yLine(length = -30)
  |> xLine(endAbsolute = eyeEndMountThickness / 2 + eyeEndMountFillet + pointOffset)
  |> close(%)

eyeEndOuterExtrude = extrude(eyeEndOuterProfile, length = 30, symmetric = true)
lowerMount = subtract([eyeEndExtrude], tools = [eyeEndOuterExtrude])

// Eye End Hole for Lower Mount
eyeEndHolePlane = offsetPlane(XZ, offset = 15)
eyeEndHoleSketch = startSketchOn(eyeEndHolePlane)
eyeEndHoleProfile = circle(
  eyeEndHoleSketch,
  center = [
    0,
    -lengthBelowRetainerPlate + eyeEndMountOuterDia / 2
  ],
  radius = eyeEndMountHoleDia / 2,
)
eyeEndHoleExtrude = extrude(eyeEndHoleProfile, length = -40)
lowerMountSolid = subtract([lowerMount], tools = [eyeEndHoleExtrude])

// Damper body above the retainer plate
damperBodySketch = startSketchOn(XY)
damperBodyProfile = circle(damperBodySketch, center = [0, 0], radius = damperBodyDia / 2)
damperBodyExtrude = extrude(damperBodyProfile, length = damperBodyLength)

// Hole for the piston shaft in the damper body
pistonShaftSketch = startSketchOn(damperBodyExtrude, face = END)
pistonShaftProfile = circle(pistonShaftSketch, center = [0, 0], radius = pistonShaftHoleDia / 2)
pistonShaftHole = extrude(pistonShaftProfile, length = -damperBodyLength)


// Coilover Top
// Part consists of a 70 mm diameter plate with a tapered mount body , and a eye-end mount (with a hole) on top of it. Below this plate/body, there is a stopper that limits the travel of the coilover, and a piston shaft below it to guide the coilover.

// Set units
@settings(defaultLengthUnit = mm, kclVersion = 1.0)

// Import parameters
import eyeEndMountOuterDia, pointOffset, eyeEndMountLength, eyeEndMountHoleDia, eyeEndMountThickness, eyeEndMountFillet, pistonRodStopDia, pistonRodStopLength, upperMountPlateDia, upperMountPlateThickness from "parameters.kcl"

// Stopper for the Piston Rod located just below Upper Mount Plate
pistonRodStopSketch = startSketchOn(XY)
pistonRodStopperProfile = circle(
  pistonRodStopSketch,
  center = [0, 0],
  radius = pistonRodStopDia / 2,
  tag = $seg01,
)

pistonRodStopperExtrude = extrude(pistonRodStopperProfile, length = -pistonRodStopLength, tagStart = $capStart001)
  |> chamfer(
       length = 6,
       tags = [
         getCommonEdge(faces = [seg01, capStart001])
       ],
     )

// Piston Rod located below the Stopper
pistonRodSketch = startSketchOn(pistonRodStopperExtrude, face = START)
pistonRodProfile = circle(pistonRodSketch, center = [0, 0], radius = 4.95)
pistonRodExtrude = extrude(pistonRodProfile, length = 200)

// Upper Mount Plate
upperMountPlateSketch = startSketchOn(pistonRodStopperExtrude, face = END)
upperMountPlateProfile = circle(
  upperMountPlateSketch,
  center = [0, 0],
  radius = upperMountPlateDia / 2,
  tag = $seg02,
)
upperMountPlateExtrude = extrude(upperMountPlateProfile, length = upperMountPlateThickness, tagEnd = $capEnd001)
  |> chamfer(
       length = 19,
       tags = [
         getCommonEdge(faces = [seg02, capEnd001])
       ],
     )

// Eye End for Upper Mount
eyeEndSketch = startSketchOn(upperMountPlateExtrude, face = END)
eyeEndProfile = circle(
  eyeEndSketch,
  center = [0, 0],
  radius = eyeEndMountOuterDia / 2,
  tag = $seg03,
)
eyeEndExtrude = extrude(eyeEndProfile, length = eyeEndMountLength, tagEnd = $capEnd002)
  |> fillet(
       radius = eyeEndMountOuterDia / 2 - 0.01,
       tags = [
         getCommonEdge(faces = [seg03, capEnd002])
       ],
     )

// Eye End Outer Profile for Upper Mount
eyeEndOuterSketch = startSketchOn(YZ)
eyeEndOuterProfile = startProfile(
       eyeEndOuterSketch,
       at = [
         eyeEndMountThickness / 2 + eyeEndMountFillet + pointOffset,
         upperMountPlateThickness + eyeEndMountLength - 25
       ],
     )
  |> xLine(length = -pointOffset)
  |> tangentialArc(radius = eyeEndMountFillet, angle = -90)
  |> yLine(length = 22)
  |> xLine(length = -eyeEndMountThickness)
  |> yLine(length = -22)
  |> tangentialArc(radius = eyeEndMountFillet, angle = -90)
  |> xLine(length = -20)
  |> yLine(length = 30)
  |> xLine(endAbsolute = eyeEndMountThickness / 2 + eyeEndMountFillet + pointOffset)
  |> close(%)

eyeEndOuterExtrude = extrude(eyeEndOuterProfile, length = 30, symmetric = true)
upperMount = subtract([eyeEndExtrude], tools = [eyeEndOuterExtrude])

// Eye End Hole for Upper Mount
eyeEndHolePlane = offsetPlane(XZ, offset = 15)
eyeEndHoleSketch = startSketchOn(eyeEndHolePlane)
eyeEndHoleProfile = circle(
  eyeEndHoleSketch,
  center = [
    0,
    upperMountPlateThickness + eyeEndMountLength - (eyeEndMountOuterDia / 2)
  ],
  radius = eyeEndMountHoleDia / 2,
)
eyeEndHoleExtrude = extrude(eyeEndHoleProfile, length = -40)
upperMountSolid = subtract([upperMount], tools = [eyeEndHoleExtrude])
  |> appearance(color = "#252318", roughness = 90, metalness = 90)


// Coilover assembly parameters
// Key dimensional parameters for all parts in the coilover assembly. These are imported into the kcl part files. Key parameters include retainer plate, eye mount, spring and piston rod dimensions.

// Set units
@settings(defaultLengthUnit = mm, kclVersion = 1.0)

// Coilover Bottom (coilover-bottom.kcl)
export retainerPlateDia = 70
export retainerPlateLength = 6.3
export baseSeatingDia = 55
export baseSeatingLength = 5
export lowerMountDia = 38
export damperBodyLength = 51
export lowerMountLength = 92
export eyeEndMountOuterDia = 25
export eyeEndMountLength = eyeEndMountOuterDia / 2 + 30
export eyeEndMountHoleDia = 12.5
export eyeEndMountThickness = 12.7
export eyeEndMountFillet = 5
export damperBodyDia = lowerMountDia
export pistonShaftHoleDia = 10
export lengthBelowRetainerPlate = baseSeatingLength + lowerMountLength + eyeEndMountLength
export lowerMountOverallLength = lengthBelowRetainerPlate + retainerPlateLength
export pointOffset = 20 // Used to help build profile for subtraction


// Coilover Spring (spring.kcl)
export springRadius = 22
export springLength = 200
export springRevolutions = 8
export coilThickness = 6

// Coilover Top (coilover-top.kcl)
export pistonRodStopDia = 25
export pistonRodStopLength = 32.5
export upperMountPlateDia = 70
export upperMountPlateThickness = 22.5
export pistonShaftDia = pistonShaftHoleDia - 0.1 // reduced shaft dia from the hole to provide some clearance


// Spring for coilover assembly
// Spring that sits on top of the retainer plate in the coilover assembly, with a piston shaft running through it. 200 mm long, with a 22 mm radius, and coils at 6 mm thick.

import springRadius, springLength, springRevolutions, coilThickness from "parameters.kcl"

helixPath = helix(
  axis = Z,
  radius = springRadius,
  length = springLength,
  revolutions = springRevolutions,
  angleStart = 360,
  ccw = false,
)

springSketch = startSketchOn(XZ)
  |> circle(center = [springRadius, 0], radius = coilThickness / 2)
  |> sweep(path = helixPath)
  |> appearance(color = "#d78109", roughness = 90, metalness = 50)


Geometry Engine

Zoo CAD Engine Overview

coilover-assembly

KCL