This is a color cube centered about the origin. It is used to help determine orientation in the scene.

// Color Cube
// This is a color cube centered about the origin. It is used to help determine orientation in the scene.
// Categories: Science & Education

// Set units
@settings(defaultLengthUnit = mm, kclVersion = 2.0)

// Parameters used to construct the cube faces
size = 100
halfSize = size / 2
extrudeLength = 1.0
metalConstant = 50
roughnessConstant = 50

// Sketch a rectangle centered at the origin of the profile
faceSketch = sketch(on = XY) {
  originToLeft = line(start = [var 0mm, var 0mm], end = [var -50mm, var 0mm], construction = true)
  leftDown = line(start = [var -50mm, var 0mm], end = [var -50mm, var -50mm], construction = true)
  bottomEdge = line(start = [var -50mm, var -50mm], end = [var 50mm, var -50mm])
  rightEdge = line(start = [var 50mm, var -50mm], end = [var 50mm, var 50mm])
  topEdge = line(start = [var 50mm, var 50mm], end = [var -50mm, var 50mm])
  leftEdge = line(start = [var -50mm, var 50mm], end = [var -50mm, var -50mm])

  coincident([originToLeft.start, ORIGIN])
  coincident([originToLeft.end, leftDown.start])
  coincident([leftDown.end, bottomEdge.start])
  coincident([bottomEdge.end, rightEdge.start])
  coincident([rightEdge.end, topEdge.start])
  coincident([topEdge.end, leftEdge.start])
  coincident([leftEdge.end, bottomEdge.start])

  horizontal(originToLeft)
  vertical(leftDown)
  horizontal(bottomEdge)
  vertical(rightEdge)
  horizontal(topEdge)
  vertical(leftEdge)

  distance([originToLeft.start, originToLeft.end]) == halfSize
  distance([leftDown.start, leftDown.end]) == halfSize
  distance([bottomEdge.start, bottomEdge.end]) == size
  distance([rightEdge.start, rightEdge.end]) == size
}

faceRegion = region(segments = [
  faceSketch.bottomEdge,
  faceSketch.rightEdge
])
faceBody = extrude(faceRegion, length = extrudeLength)
  |> translate(z = -extrudeLength / 2, global = true)
hide(faceSketch)

// Position and color each side of the cube
blueBody = clone(faceBody)
  |> translate(z = halfSize + extrudeLength / 2, global = true)
yellowBody = clone(faceBody)
  |> translate(z = -halfSize + extrudeLength / 2, global = true)
greenBody = clone(faceBody)
  |> rotate(axis = X, angle = 90deg)
  |> translate(y = halfSize - (extrudeLength / 2), global = true)
purpleBody = clone(faceBody)
  |> rotate(axis = X, angle = -90deg)
  |> translate(y = -halfSize + extrudeLength / 2, global = true)
redBody = clone(faceBody)
  |> rotate(axis = Y, angle = 90deg)
  |> translate(x = halfSize - (extrudeLength / 2), global = true)
tealBody = faceBody
  |> rotate(axis = Y, angle = 90deg)
  |> translate(x = -halfSize + extrudeLength / 2, global = true)

blueFace = appearance(
  blueBody,
  color = "#0000FF",
  metalness = metalConstant,
  roughness = roughnessConstant,
)

yellowFace = appearance(
  yellowBody,
  color = "#FFFF00",
  metalness = metalConstant,
  roughness = roughnessConstant,
)

greenFace = appearance(
  greenBody,
  color = "#00FF00",
  metalness = metalConstant,
  roughness = roughnessConstant,
)

redFace = appearance(
  redBody,
  color = "#FF0000",
  metalness = metalConstant,
  roughness = roughnessConstant,
)

tealFace = appearance(
  tealBody,
  color = "#00FFFF",
  metalness = metalConstant,
  roughness = roughnessConstant,
)

purpleFace = appearance(
  purpleBody,
  color = "#FF00FF",
  metalness = metalConstant,
  roughness = roughnessConstant,
)


Color Cube

Zookeeper

Zookeeper: The Conversational CAD Agent For Parametric Modeling

Automation

Automating Your Workflow

File Formats

A Practical Overview of CAD File Formats

KCL: A Programming Language for Parametric CAD

Geometry Engine

Zoo CAD Engine Overview