A 4 axis robotic arm for industrial use. These machines can be used for assembly, packaging, organization of goods, and quality inspection processes

// Robot Arm
// A 4 axis robotic arm for industrial use. These machines can be used for assembly, packaging, organization of goods, and quality inspection processes
// Categories: Manufacturing, Automotive

// Set Units
@settings(defaultLengthUnit = in, kclVersion = 1.0)

// Import parts
import "robot-arm-base.kcl" as robotArmBase
import "robot-rotating-base.kcl" as rotatingBase
import "robot-arm-j2.kcl" as j2RobotArm
import "robot-arm-j3.kcl" as j3RobotArm

robotArmBase
rotatingBase
j2RobotArm
j3RobotArm


// Global constants for the multi-axis robot

// Set Units
@settings(defaultLengthUnit = in, kclVersion = 1.0)

// Axis Angles
export axisJ4 = 25deg
export axisJ3 = 60deg
export axisJ2 = 110deg
export axisJ1 = 80deg

// Robot Arm Base
export basePlateRadius = 5.5
export basePlateThickness = 0.5
export baseChamfer = 2
export baseHeight = 5

// J2 Axis for Robot Arm
export axisJ2ArmLength = 31
export axisJ2ArmWidth = 4
export axisJ2ArmThickness = 2.5

// J3 Axis for Robot Arm
export axisJ3C = axisJ3 - 180 + axisJ2
export axisJ3CArmLength = 20
export axisJ3CArmWidth = 3.75
export axisJ3CArmThickness = 2.5

// Planes
export plane001 = {
  origin = [0.0, 0.0, baseHeight - 1.5 + 0.1],
  xAxis = [1.0, 0.0, 0.0],
  yAxis = [0.0, 1.0, 0.0]
}

export plane002 = {
  origin = [0.0, 0.0, 0.0],
  xAxis = [sin(axisJ1): in, cos(axisJ1): in, 0.0],
  yAxis = [0.0, 0.0, 1.0]
}

// Define Plane to Move J2 Axis Robot Arm
export plane003 = {
  origin = [-0.1, 0.0, 0.0],
  xAxis = [sin(axisJ1): in, cos(axisJ1): in, 0.0],
  yAxis = [0.0, 0.0, 1.0]
}


// Robot Arm Base

// Set Units
@settings(defaultLengthUnit = in, kclVersion = 1.0)

// Import Constants
import basePlateRadius, basePlateThickness, baseChamfer, baseHeight from "globals.kcl"

// Pattern M8 mounting bolts in base
mountingHoles01 = startSketchOn(XY)
  |> circle(
       center = [
         -basePlateRadius + 1,
         -basePlateRadius + baseChamfer + 0.5
       ],
       radius = 0.4,
     )
  |> patternCircular2d(center = [0, 0], instances = 4)

mountingHoles02 = startSketchOn(XY)
  |> circle(
       center = [
         -basePlateRadius + 0.5 + baseChamfer,
         -basePlateRadius + 1
       ],
       radius = 0.4,
     )
  |> patternCircular2d(center = [0, 0], instances = 4)

// Base Plate
sketch001 = startSketchOn(XY)
  |> startProfile(at = [-basePlateRadius, -basePlateRadius])
  |> angledLine(angle = 0, length = 2 * basePlateRadius, tag = $rectangleSegmentA001)
  |> angledLine(angle = segAng(rectangleSegmentA001) + 90, length = 2 * basePlateRadius, tag = $rectangleSegmentB001)
  |> angledLine(angle = segAng(rectangleSegmentA001), length = -segLen(rectangleSegmentA001), tag = $rectangleSegmentC001)
  |> line(endAbsolute = [profileStartX(%), profileStartY(%)], tag = $rectangleSegmentD001)
  |> close()
  |> subtract2d(tool = [mountingHoles01, mountingHoles02])
  |> extrude(length = basePlateThickness)
  |> chamfer(
       length = baseChamfer,
       tags = [
         getNextAdjacentEdge(rectangleSegmentA001),
         getNextAdjacentEdge(rectangleSegmentB001),
         getNextAdjacentEdge(rectangleSegmentC001),
         getNextAdjacentEdge(rectangleSegmentD001)
       ],
     )

// Base Motor for actuating first joint
sketch002 = startSketchOn(sketch001, face = END)
  |> circle(center = [0, 0], radius = 4, tag = $referenceEdge)
extrude002 = extrude(sketch002, length = baseHeight - basePlateThickness - 1.5)
  |> fillet(radius = 0.1, tags = [getOppositeEdge(referenceEdge)])
sketch003 = startSketchOn(extrude002, face = END)
  |> circle(center = [0, 0], radius = 0.5)
extrude003 = extrude(sketch003, length = 1)
  |> appearance(color = "#754110", roughness = 90, metalness = 90)


// J2 Axis for Robot Arm

// Set Units
@settings(defaultLengthUnit = in, kclVersion = 1.0)

import axisJ1, axisJ2, axisJ2ArmWidth, axisJ2ArmLength, axisJ2ArmThickness, plane003 from "globals.kcl"

// Create Body of J2 Robot Arm
sketch011 = startSketchOn(plane003)
  |> startProfile(at = [
       1.75 - (axisJ2ArmWidth / 2 * sin(axisJ2)),
       8 + axisJ2ArmWidth / 2 * cos(axisJ2)
     ])
  |> arc(angleStart = 90 + axisJ2, angleEnd = 270 + axisJ2, radius = axisJ2ArmWidth / 2)
  |> angledLine(angle = axisJ2, length = axisJ2ArmLength)
  |> arc(angleStart = -90 + axisJ2, angleEnd = 90 + axisJ2, radius = axisJ2ArmWidth / 2)
  |> line(endAbsolute = [profileStartX(%), profileStartY(%)])
  |> close()
extrude011 = extrude(sketch011, length = -axisJ2ArmThickness)

sketch012 = startSketchOn(extrude011, face = START)
  |> circle(center = [-1.75, 8], radius = 1.9, tag = $referenceEdge4)

extrude012 = extrude(sketch012, length = 0.15)
  |> fillet(radius = 0.1, tags = [getOppositeEdge(referenceEdge4)])
sketch013 = startSketchOn(extrude011, face = START)
  |> circle(
       center = [
         -1.75 - (axisJ2ArmLength * cos(axisJ2)),
         8 + axisJ2ArmLength * sin(axisJ2)
       ],
       radius = 1.9,
       tag = $referenceEdge5,
     )

extrude013 = extrude(sketch013, length = 1)
  |> fillet(radius = 0.1, tags = [getOppositeEdge(referenceEdge5)])

// Draw Bolt Patterns on J2 Robot Arm
sketch014 = startSketchOn(extrude012, face = END)
  |> circle(center = [-1.75, 6.75], radius = 0.2)
  |> patternCircular2d(
       center = [-1.75, 8],
       instances = 8,
       arcDegrees = 360,
       rotateDuplicates = true,
     )

extrude014 = extrude(sketch014, length = 0.15)

sketch015 = startSketchOn(extrude013, face = END)
  |> circle(
       center = [
         -1.75 - ((axisJ2ArmLength - 1) * cos(axisJ2)),
         8 + (axisJ2ArmLength - 1.5) * sin(axisJ2)
       ],
       radius = 0.2,
     )
  |> patternCircular2d(
       center = [
         -1.75 - (axisJ2ArmLength * cos(axisJ2)),
         8 + axisJ2ArmLength * sin(axisJ2)
       ],
       instances = 4,
       arcDegrees = 360,
       rotateDuplicates = true,
     )

extrude015 = extrude(sketch015, length = 0.15)

sketch016 = startSketchOn(extrude011, face = END)
  |> circle(
       center = [
         1.75 + axisJ2ArmLength * cos(axisJ2),
         8 + axisJ2ArmLength * sin(axisJ2)
       ],
       radius = 0.3,
     )

extrude(sketch016, length = 1)
  |> appearance(color = "#454545", metalness = 90, roughness = 90)


// J3 Robot Arm

// Set Units
@settings(defaultLengthUnit = in, kclVersion = 1.0)

import plane002, axisJ2, axisJ3C, axisJ4, axisJ2ArmLength, axisJ3CArmLength, axisJ3CArmWidth, axisJ3CArmThickness from "globals.kcl"

// Create Body of J3 Robot Arm
sketch017 = startSketchOn(plane002)
  |> startProfile(at = [
       1.75 + axisJ2ArmLength * cos(axisJ2) - (axisJ3CArmWidth / 2 * sin(axisJ3C)),
       8 + axisJ2ArmLength * sin(axisJ2) + axisJ3CArmWidth / 2 * cos(axisJ3C)
     ])
  |> arc(angleStart = 90 + axisJ3C, angleEnd = 270 + axisJ3C, radius = axisJ3CArmWidth / 2)
  |> angledLine(angle = axisJ3C, length = axisJ3CArmLength)
  |> arc(angleStart = 270 + axisJ3C, angleEnd = 90 + axisJ3C, radius = axisJ3CArmWidth / 2)
  |> line(endAbsolute = [profileStartX(%), profileStartY(%)], tag = $seg01)
  |> close()
extrude017 = extrude(sketch017, length = axisJ3CArmThickness)

sketch018 = startSketchOn(extrude017, face = END)
  |> circle(
       center = [
         1.75 + axisJ2ArmLength * cos(axisJ2),
         8 + axisJ2ArmLength * sin(axisJ2)
       ],
       radius = 3.7 / 2,
       tag = $referenceEdge6,
     )

extrude018 = extrude(sketch018, length = 0.15)
  |> fillet(radius = 0.1, tags = [getOppositeEdge(referenceEdge6)])

// Draw Bolt Pattern on J3 Robot Arm
sketch019 = startSketchOn(extrude018, face = END)
  |> circle(
       center = [
         1.75 + (axisJ2ArmLength - 1) * cos(axisJ2),
         8 + (axisJ2ArmLength - 1.5) * sin(axisJ2)
       ],
       radius = 0.2,
     )
  |> patternCircular2d(
       center = [
         1.75 + axisJ2ArmLength * cos(axisJ2),
         8 + axisJ2ArmLength * sin(axisJ2)
       ],
       instances = 8,
       arcDegrees = 360,
       rotateDuplicates = true,
     )

extrude019 = extrude(sketch019, length = 0.15)

// On the J3 Robot Arm Body, Create Mounting Clevis for Grabber Claw
sketch020 = startSketchOn(extrude017, face = START)
  |> circle(
       center = [
         -1.75 - (axisJ2ArmLength * cos(axisJ2)) - (axisJ3CArmLength * cos(axisJ3C)),
         8 + axisJ2ArmLength * sin(axisJ2) + axisJ3CArmLength * sin(axisJ3C)
       ],
       radius = axisJ3CArmWidth / 2,
     )
extrude020 = extrude(sketch020, length = -0.5, method = NEW)

sketch021 = startSketchOn(extrude017, face = END)
  |> circle(
       center = [
         1.75 + axisJ2ArmLength * cos(axisJ2) + axisJ3CArmLength * cos(axisJ3C),
         8 + axisJ2ArmLength * sin(axisJ2) + axisJ3CArmLength * sin(axisJ3C)
       ],
       radius = axisJ3CArmWidth / 2.01,
     )

extrude021 = extrude(sketch021, length = -0.5, method = NEW)

// Define Grabber Claw Constants
grabberLength = 7

sketch022 = startSketchOn(extrude021, face = START)
  |> circle(center = [0, 0], radius = 0.10)

extrude022 = extrude(sketch022, length = -0.01)

// Build Upper Claw Finger
sketch023 = startSketchOn(extrude022, face = START)
  |> startProfile(at = [
       1.75 + axisJ2ArmLength * cos(axisJ2) + axisJ3CArmLength * cos(axisJ3C),
       8 + axisJ2ArmLength * sin(axisJ2) + axisJ3CArmLength * sin(axisJ3C)
     ])
  |> angledLine(angle = axisJ3C, length = grabberLength / 4)
  |> arc(angleStart = 150 + axisJ3C, angleEnd = 30 + axisJ3C, radius = grabberLength / 3)
  |> angledLine(angle = axisJ3C, length = grabberLength / 6)
  |> angledLine(angle = axisJ3C + 132, length = grabberLength / 3.5)
  |> angledLine(angle = axisJ3C + 160, length = grabberLength / 3.5)
  |> angledLine(angle = axisJ3C + 200, length = grabberLength / 3)
  |> line(endAbsolute = [profileStartX(%), profileStartY(%)])
  |> close()

extrude023 = extrude(sketch023, length = -1.5, method = NEW)

// Build Lower Claw Finger
sketch024 = startSketchOn(extrude022, face = START)
  |> startProfile(at = [
       1.75 + axisJ2ArmLength * cos(axisJ2) + axisJ3CArmLength * cos(axisJ3C),
       8 + axisJ2ArmLength * sin(axisJ2) + axisJ3CArmLength * sin(axisJ3C)
     ])
  |> angledLine(angle = axisJ3C, length = grabberLength / 4)
  |> arc(angleStart = 210 + axisJ3C, angleEnd = 330 + axisJ3C, radius = grabberLength / 3)
  |> angledLine(angle = axisJ3C, length = grabberLength / 6)
  |> angledLine(angle = axisJ3C - 132, length = grabberLength / 3.5)
  |> angledLine(angle = axisJ3C - 160, length = grabberLength / 3.5)
  |> angledLine(angle = axisJ3C - 200, length = grabberLength / 3)
  |> line(endAbsolute = [profileStartX(%), profileStartY(%)])
  |> close()

extrude024 = extrude(sketch024, length = -1.5, method = NEW)
appearance(
  [
    extrude020,
    extrude021,
    extrude023,
    extrude024
  ],
  color = "#6572b3",
  metalness = 90,
  roughness = 90,
)


// Robot Rotating Base

// Set Units
@settings(defaultLengthUnit = in, kclVersion = 1.0)

import axisJ1, baseHeight, plane001, plane002 from "globals.kcl"

// Create Rotating Base
sketch005 = startSketchOn(plane001)
  |> circle(center = [0, 0], radius = 3.9, tag = $referenceEdge1)
extrude005 = extrude(sketch005, length = 1.5 - 0.1)
  |> fillet(radius = 0.1, tags = [getOppositeEdge(referenceEdge1)])
  |> appearance(color = "#4f7d54", metalness = 90, roughness = 90)

sketch006 = startSketchOn(plane002)
  |> startProfile(at = [3.5, baseHeight])
  |> angledLine(angle = 60, length = 1.75)
  |> arc(angleStart = -30, angleEnd = -30 + 180, radius = 3)
  |> angledLine(angle = 60, endAbsoluteY = baseHeight)
  |> line(endAbsolute = [profileStartX(%), profileStartY(%)])
  |> close()

extrude006 = extrude(sketch006, length = 1)

sketch007 = startSketchOn(extrude006, face = END)
  |> circle(
       center = [
         1.75 * cos(axisJ1) / abs(cos(axisJ1)),
         8
       ],
       radius = 2.75,
       tag = $referenceEdge2,
     )
extrude007 = extrude(sketch007, length = 1.5)
  |> fillet(radius = 0.1, tags = [getOppositeEdge(referenceEdge2)])

// Draw Bolt Pattern on Rotating Base
sketch008 = startSketchOn(extrude007, face = END)
  |> circle(
       center = [
         1.75 * cos(axisJ1) / abs(cos(axisJ1)),
         6.75
       ],
       radius = 0.2,
     )
  |> patternCircular2d(
       center = [
         1.75 * cos(axisJ1) / abs(cos(axisJ1)),
         8
       ],
       instances = 4,
       arcDegrees = 360,
       rotateDuplicates = true,
     )
extrude008 = extrude(sketch008, length = 0.2)

sketch009 = startSketchOn(extrude007, face = END)
  |> circle(
       center = [
         1.75 * cos(axisJ1) / abs(cos(axisJ1)),
         8
       ],
       radius = 0.5,
       tag = $referenceEdge3,
     )
extrude009 = extrude(sketch009, length = 0.15)
  |> fillet(radius = 0.1, tags = [getOppositeEdge(referenceEdge3)])
  |> appearance(color = "#4f7d54", metalness = 90, roughness = 90)

sketch010 = startSketchOn(plane002)
  |> circle(center = [1.75, 8], radius = 0.3)

extrude(sketch010, length = -1)


Geometry Engine

Zoo CAD Engine Overview

multi-axis-robot

KCL