Modular construction of the iconic multi-stage rocket using parametric and revolve-based shapes

// Saturn V Rocket
// Modular construction of the iconic multi-stage rocket using parametric and revolve-based shapes
// Categories: Aerospace; Science & Education; Parametric

@settings(defaultLengthUnit = m, kclVersion = 2.0)

r1 = 4.5 // baseRadiusStage1
r2 = 3.2 // baseRadiusUpperStage
transitionRadius = 3.85

// ----------------------------
// --- Engine Nozzles (x4) ---
// ----------------------------
// Created with revolve profiles to model conic nozzles; cloned and rotated to form quad layout


nozzleProfile = sketch(on = YZ) {
  line1 = line(start = [var -0.1m, var 0m], end = [var -0.1m, var 9m])
  line2 = line(start = [var -0.1m, var 9m], end = [var -2.4m, var 0m])
  line3 = line(start = [var -2.4m, var 0m], end = [var -0.1m, var 0m])
  line4 = line(start = [var -0.1m, var 0m], end = [var 0m, var 0m], construction = true)
  coincident([line1.end, line2.start])
  coincident([line2.end, line3.start])
  coincident([line3.end, line1.start])
  coincident([line4.start, line1.start])
  coincident([line4.end, ORIGIN])
  vertical(line1)
  horizontal(line3)
  horizontal(line4)
  horizontalDistance([line3.start, line3.end]) == 2.3
  verticalDistance([line1.start, line1.end]) == 9
  horizontalDistance([line4.start, line4.end]) == 0.1
}
region001 = region(segments = [nozzleProfile.line1])
nozzle1 = revolve(region001, angle = 360, axis = Y)
  |> translate(
       x = -r1,
       y = 0,
       z = 0,
       global = true,
     )
  |> appearance(color = "#292929")
nozzle2 = clone(nozzle1)
  |> rotate(
       roll = 0,
       pitch = 0,
       yaw = 90,
       global = true,
     )
nozzle3 = clone(nozzle1)
  |> rotate(
       roll = 0,
       pitch = 0,
       yaw = 180,
       global = true,
     )
nozzle4 = clone(nozzle1)
  |> rotate(
       roll = 0,
       pitch = 0,
       yaw = 270,
       global = true,
     )

// ------------------------------------
// --- Nozzle Hoods (Alternating) ---
// ------------------------------------
// Modeled identically to nozzles but translated upward and given alternating colors


hoodProfile = sketch(on = YZ) {
  line1 = line(start = [var -0.1m, var 0m], end = [var -0.1m, var 8.5m])
  line2 = line(start = [var -0.1m, var 8.5m], end = [var -2.2m, var 0m])
  line3 = line(start = [var -2.2m, var 0m], end = [var -0.1m, var 0m])
  line4 = line(start = [var 0m, var 0m], end = [var -0.1m, var 0m], construction = true)
  coincident([line1.end, line2.start])
  coincident([line2.end, line3.start])
  coincident([line3.end, line1.start])
  coincident([line4.start, ORIGIN])
  coincident([line4.end, line1.start])
  vertical(line1)
  horizontal(line3)
  horizontal(line4)
  horizontalDistance([line4.end, line4.start]) == 0.1
  horizontalDistance([line3.start, line3.end]) == 2.1
  verticalDistance([line1.start, line1.end]) == 8.5
}
region002 = region(segments = [hoodProfile.line1, hoodProfile.line2])
hood1 = revolve(region002, angle = 360, axis = Y)
  |> translate(
       x = -r1,
       y = 0,
       z = 4,
       global = true,
     )
  |> appearance(color = "#ffffff")
hood2 = clone(hood1)
  |> rotate(
       roll = 0,
       pitch = 0,
       yaw = 90,
       global = true,
     )
  |> appearance(color = "#000000")
hood3 = clone(hood1)
  |> rotate(
       roll = 0,
       pitch = 0,
       yaw = 180,
       global = true,
     )
  |> appearance(color = "#ffffff")
hood4 = clone(hood1)
  |> rotate(
       roll = 0,
       pitch = 0,
       yaw = 270,
       global = true,
     )
  |> appearance(color = "#000000")

// ----------------------------
// --- Stabilizer Fins (x4) ---
// ----------------------------
// Small extrusions in X-Y profile, rotated to form cross pattern


finProfile = sketch(on = YZ) {
  line1 = line(start = [var -4m, var 6m], end = [var -7.6m, var 6m])
  line2 = line(start = [var -7.6m, var 6m], end = [var -7.6m, var 8.2m])
  line3 = line(start = [var -7.6m, var 8.2m], end = [var -4m, var 11.2m])
  line4 = line(start = [var -4m, var 11.2m], end = [var -4m, var 6m])
  coincident([line1.end, line2.start])
  coincident([line2.end, line3.start])
  coincident([line3.end, line4.start])
  coincident([line4.end, line1.start])
  horizontal(line1)
  vertical(line2)
  vertical(line4)
  horizontalDistance([line1.start, ORIGIN]) == 4
  verticalDistance([ORIGIN, line1.start]) == 6
  horizontalDistance([line1.end, line1.start]) == 3.6
  verticalDistance([line2.start, line2.end]) == 2.2
  verticalDistance([line4.end, line4.start]) == 5.2
}
region003 = region(segments = [finProfile.line1, finProfile.line2])
fin1 = extrude(region003, length = 0.1)
  |> appearance(color = "#ffffff")
fin2 = clone(fin1)
  |> rotate(
       roll = 0,
       pitch = 0,
       yaw = 90,
       global = true,
     )
fin3 = clone(fin1)
  |> rotate(
       roll = 0,
       pitch = 0,
       yaw = 180,
       global = true,
     )
fin4 = clone(fin1)
  |> rotate(
       roll = 0,
       pitch = 0,
       yaw = 270,
       global = true,
     )

// -------------------------------
// --- Stage 1: Bottom Section ---
// -------------------------------
// Uses split white/black geometry to emulate paint scheme with mirrored arcs


bottomBasePlane = offsetPlane(XY, offset = 6)
blackPanelProfile = sketch(on = bottomBasePlane) {
  line1 = line(start = [var 0m, var -4.5m], end = [var 0m, var 4.5m])
  arc2 = arc(start = [var 0m, var -4.5m], end = [var 0m, var 4.5m], center = [var 0m, var 0m])
  coincident([line1.start, arc2.start])
  coincident([line1.end, arc2.end])
  vertical(line1)
  coincident([arc2.center, line1])
  coincident([arc2.center, ORIGIN])
  radius(arc2) == r1
}
region004 = region(segments = [
  blackPanelProfile.line1,
  blackPanelProfile.arc2
])
blackPanel = extrude(region004, length = 14)
  |> appearance(color = "#000000")

whitePanelProfile = sketch(on = bottomBasePlane) {
  line1 = line(start = [var 0m, var -4.5m], end = [var 0m, var 4.5m])
  arc2 = arc(start = [var 0m, var 4.5m], end = [var 0m, var -4.5m], center = [var 0m, var 0m])
  coincident([line1.end, arc2.start])
  coincident([line1.start, arc2.end])
  vertical(line1)
  coincident([arc2.center, line1])
  coincident([arc2.center, ORIGIN])
  radius(arc2) == r1
}
region005 = region(segments = [
  whitePanelProfile.line1,
  whitePanelProfile.arc2
])
whitePanel = extrude(region005, length = 14)
  |> appearance(color = "#ffffff")

// ------------------------------
// --- Stage 1: Upper Section ---
// ------------------------------
// Alternating black and white zones using circular cross-sections


cylinderBasePlane = offsetPlane(XY, offset = 20)
stage1CylinderProfile = sketch(on = cylinderBasePlane) {
  circle1 = circle(start = [var 4.5m, var 0m], center = [var 0m, var 0m])
  coincident([circle1.center, ORIGIN])
  diameter(circle1) == 2 * r1
}
region006 = region(segments = [stage1CylinderProfile.circle1])
stage1Cylinder = extrude(region006, length = 18)
  |> appearance(color = "#ffffff")

midStripePlane = offsetPlane(XY, offset = 38)
midStripeProfileBlack = sketch(on = midStripePlane) {
  line1 = line(start = [var -4.5m, var 0m], end = [var 4.5m, var 0m])
  arc2 = arc(start = [var 4.5m, var 0m], end = [var -4.5m, var 0m], center = [var 0m, var 0m])
  coincident([line1.end, arc2.start])
  coincident([line1.start, arc2.end])
  horizontal(line1)
  coincident([arc2.center, line1])
  coincident([arc2.center, ORIGIN])
  radius(arc2) == r1
}
region007 = region(segments = [
  midStripeProfileBlack.line1,
  midStripeProfileBlack.arc2
])
midStripeBlack = extrude(region007, length = 9)
  |> appearance(color = "#000000")

// White
midStripeProfileWhite = sketch(on = midStripePlane) {
  line1 = line(start = [var -4.5m, var 0m], end = [var 4.5m, var 0m])
  arc2 = arc(start = [var -4.5m, var 0m], end = [var 4.5m, var 0m], center = [var 0m, var 0m])
  coincident([line1.start, arc2.start])
  coincident([line1.end, arc2.end])
  horizontal(line1)
  coincident([arc2.center, line1])
  coincident([arc2.center, ORIGIN])
  radius(arc2) == r1
}
region008 = region(segments = [
  midStripeProfileWhite.line1,
  midStripeProfileWhite.arc2
])
midStripeWhite = extrude(region008, length = 9)
  |> appearance(color = "#ffffff")

// Ring
ringPlane = offsetPlane(XY, offset = 47)
ringProfile = sketch(on = ringPlane) {
  circle1 = circle(start = [var 4.5m, var 0m], center = [var 0m, var 0m])
  coincident([circle1.center, ORIGIN])
  diameter(circle1) == 2 * r1
}
region009 = region(segments = [ringProfile.circle1])
ringBand = extrude(region009, length = 2)
  |> appearance(color = "#000000")

// Upper Cyl
upperCylPlane = offsetPlane(XY, offset = 49)
upperCylProfile = sketch(on = upperCylPlane) {
  circle1 = circle(start = [var 4.5m, var 0m], center = [var 0m, var 0m])
  coincident([circle1.center, ORIGIN])
  diameter(circle1) == 2 * r1
}
region010 = region(segments = [upperCylProfile.circle1])
upperStage1 = extrude(region010, length = 15)
  |> appearance(color = "#ffffff")

// --------------------------------
// --- Stage Transition Cones ---
// --------------------------------
// This conic taper transitions between stage diameters

// lower cones
transitionLowerConeWhiteProfile = sketch(on = YZ) {
  line1 = line(start = [var 0m, var 64m], end = [var -4.5m, var 64m])
  line2 = line(start = [var -4.5m, var 64m], end = [var -3.85m, var 66.5m])
  line3 = line(start = [var -3.85m, var 66.5m], end = [var 0m, var 66.5m])
  line4 = line(start = [var 0m, var 66.5m], end = [var 0m, var 64m])
  coincident([line1.end, line2.start])
  coincident([line2.end, line3.start])
  coincident([line3.end, line4.start])
  coincident([line4.end, line1.start])
  horizontal(line1)
  horizontal(line3)
  vertical(line4)
  horizontalDistance([line1.start, ORIGIN]) == 0
  verticalDistance([ORIGIN, line1.start]) == 64
  horizontalDistance([line1.end, line1.start]) == r1
  horizontalDistance([line3.start, line3.end]) == transitionRadius
  verticalDistance([line4.end, line4.start]) == 2.5
}
region011 = region(segments = [
  transitionLowerConeWhiteProfile.line1,
  transitionLowerConeWhiteProfile.line2
])
transitionLowerConeWhite = revolve(region011, angle = 180, axis = Y)
  |> appearance(color = "#ffffff")

transitionLowerConeBlackProfile = sketch(on = YZ) {
  line1 = line(start = [var 0m, var 64m], end = [var -4.5m, var 64m])
  line2 = line(start = [var -4.5m, var 64m], end = [var -3.85m, var 66.5m])
  line3 = line(start = [var -3.85m, var 66.5m], end = [var 0m, var 66.5m])
  line4 = line(start = [var 0m, var 66.5m], end = [var 0m, var 64m])
  coincident([line1.end, line2.start])
  coincident([line2.end, line3.start])
  coincident([line3.end, line4.start])
  coincident([line4.end, line1.start])
  horizontal(line1)
  horizontal(line3)
  vertical(line4)
  horizontalDistance([line1.start, ORIGIN]) == 0
  verticalDistance([ORIGIN, line1.start]) == 64
  horizontalDistance([line1.end, line1.start]) == r1
  horizontalDistance([line3.start, line3.end]) == transitionRadius
  verticalDistance([line4.end, line4.start]) == 2.5
}
region012 = region(segments = [
  transitionLowerConeBlackProfile.line1,
  transitionLowerConeBlackProfile.line2
])
transitionLowerConeBlack = revolve(region012, angle = -180, axis = Y)
  |> appearance(color = "#000000")

// upper cones
transitionUpperConeBlackProfile = sketch(on = YZ) {
  line1 = line(start = [var 0m, var 66.5m], end = [var -3.85m, var 66.5m])
  line2 = line(start = [var -3.85m, var 66.5m], end = [var -3.2m, var 69m])
  line3 = line(start = [var -3.2m, var 69m], end = [var 0m, var 69m])
  line4 = line(start = [var 0m, var 69m], end = [var 0m, var 66.5m])
  coincident([line1.end, line2.start])
  coincident([line2.end, line3.start])
  coincident([line3.end, line4.start])
  coincident([line4.end, line1.start])
  horizontal(line1)
  horizontal(line3)
  vertical(line4)
  horizontalDistance([line1.start, ORIGIN]) == 0
  verticalDistance([ORIGIN, line1.start]) == 66.5
  horizontalDistance([line1.end, line1.start]) == transitionRadius
  horizontalDistance([line3.start, line3.end]) == r2
  verticalDistance([line4.end, line4.start]) == 2.5
}
region013 = region(segments = [
  transitionUpperConeBlackProfile.line1,
  transitionUpperConeBlackProfile.line2
])
transitionUpperConeBlack = revolve(region013, angle = 180, axis = Y)
  |> appearance(color = "#000000")

transitionUpperConeWhiteProfile = sketch(on = YZ) {
  line1 = line(start = [var 0m, var 66.5m], end = [var -3.85m, var 66.5m])
  line2 = line(start = [var -3.85m, var 66.5m], end = [var -3.2m, var 69m])
  line3 = line(start = [var -3.2m, var 69m], end = [var 0m, var 69m])
  line4 = line(start = [var 0m, var 69m], end = [var 0m, var 66.5m])
  coincident([line1.end, line2.start])
  coincident([line2.end, line3.start])
  coincident([line3.end, line4.start])
  coincident([line4.end, line1.start])
  horizontal(line1)
  horizontal(line3)
  vertical(line4)
  horizontalDistance([line1.start, ORIGIN]) == 0
  verticalDistance([ORIGIN, line1.start]) == 66.5
  horizontalDistance([line1.end, line1.start]) == transitionRadius
  horizontalDistance([line3.start, line3.end]) == r2
  verticalDistance([line4.end, line4.start]) == 2.5
}
region014 = region(segments = [
  transitionUpperConeWhiteProfile.line1,
  transitionUpperConeWhiteProfile.line2
])
transitionUpperConeWhite = revolve(region014, angle = -180, axis = Y)
  |> appearance(color = "#ffffff")

// ----------------------------
// --- Stage 2: Upper Body ---
// ----------------------------
// Simple white and black stack of extruded cylinders

// white
stage2Plane = offsetPlane(XY, offset = 69)
stage2Profile = sketch(on = stage2Plane) {
  circle1 = circle(start = [var 3.2m, var 0m], center = [var 0m, var 0m])
  coincident([circle1.center, ORIGIN])
  diameter(circle1) == 2 * r2
}
region015 = region(segments = [stage2Profile.circle1])
stage2White = extrude(region015, length = 9)
  |> appearance(color = "#ffffff")

// black
stage2StripePlane = offsetPlane(XY, offset = 78)
stage2StripeProfile = sketch(on = stage2StripePlane) {
  circle1 = circle(start = [var 3.2m, var 0m], center = [var 0m, var 0m])
  coincident([circle1.center, ORIGIN])
  diameter(circle1) == 2 * r2
}
region016 = region(segments = [stage2StripeProfile.circle1])
stage2Black = extrude(region016, length = 2)
  |> appearance(color = "#000000")

// ----------------------------
// --- Launch Escape System ---
// ----------------------------
// Final tapered nose modeled using a revolve profile for a sleek profile


lesProfile = sketch(on = XZ) {
  line1 = line(start = [var 0m, var 80m], end = [var -3.2m, var 80m])
  line2 = line(start = [var -3.2m, var 80m], end = [var -1.45m, var 87.2m])
  line3 = line(start = [var -1.45m, var 87.2m], end = [var -1.45m, var 91.2m])
  line4 = line(start = [var -1.45m, var 91.2m], end = [var -0.45m, var 92.4m])
  line5 = line(start = [var -0.45m, var 92.4m], end = [var -0.45m, var 99.4m])
  line6 = line(start = [var -0.45m, var 99.4m], end = [var 0m, var 100m])
  line7 = line(start = [var 0m, var 100m], end = [var 0m, var 80m])
  coincident([line1.end, line2.start])
  coincident([line2.end, line3.start])
  coincident([line3.end, line4.start])
  coincident([line4.end, line5.start])
  coincident([line5.end, line6.start])
  coincident([line6.end, line7.start])
  coincident([line7.end, line1.start])
  horizontal(line1)
  vertical(line3)
  vertical(line5)
  vertical(line7)
  horizontalDistance([line1.start, ORIGIN]) == 0
  verticalDistance([ORIGIN, line1.start]) == 80
  horizontalDistance([line1.end, line1.start]) == r2
  horizontalDistance([line2.start, line2.end]) == 1.75
  verticalDistance([line2.start, line2.end]) == 7.2
  verticalDistance([line3.start, line3.end]) == 4
  horizontalDistance([line4.start, line4.end]) == 1
  verticalDistance([line4.start, line4.end]) == 1.2
  verticalDistance([line5.start, line5.end]) == 7
  horizontalDistance([line6.start, line6.end]) == 0.45
  verticalDistance([line6.start, line6.end]) == 0.6
}
region017 = region(segments = [lesProfile.line1, lesProfile.line2])
launchEscapeSystem = revolve(region017, angle = 360, axis = Y)
  |> appearance(color = "#FFFFFF")


Saturn V Rocket

Zookeeper

Zookeeper: The Conversational CAD Agent For Parametric Modeling

Automation

Automating Your Workflow

File Formats

A Practical Overview of CAD File Formats

KCL: A Programming Language for Parametric CAD

Geometry Engine

Zoo CAD Engine Overview