Simple metal table with rectangular tabletop and four legs with a square section

// Rectangle Table
// Simple metal table with rectangular tabletop and four legs with a square section
// Categories: Construction, Maker

@settings(defaultLengthUnit = mm)

// Parameters
tableHeight = 750
tableLength = 1500
tableWidth = 600
tableTopThickness = 40
legThickness = 40

// Derived parameters
legHeight = tableHeight - tableTopThickness

// Tabletop
tableTopPlane = offsetPlane(XY, offset = tableHeight)
tableTopSketch = startSketchOn(tableTopPlane)
tableTopProfile = sketch(on = tableTopSketch) {
  line1 = line(start = [var 0mm, var 0mm], end = [var 0mm, var 1500mm])
  line2 = line(start = [var 0mm, var 1500mm], end = [var 600mm, var 1500mm])
  coincident([line1.end, line2.start])
  line3 = line(start = [var 600mm, var 1500mm], end = [var 600mm, var 0mm])
  coincident([line2.end, line3.start])
  line4 = line(start = [var 600mm, var 0mm], end = [var 0mm, var 0mm])
  coincident([line3.end, line4.start])
  vertical(line1)
  horizontal(line2)
  vertical(line3)
  distance([line1.start, line1.end]) == tableLength
  distance([line2.start, line2.end]) == tableWidth
}
region001 = region(segments = [
  tableTopProfile.line1,
  tableTopProfile.line2
])
tableTopExtrude = extrude(region001, length = -tableTopThickness)

// Leg
legSketch = startSketchOn(XY)
legProfile = sketch(on = legSketch) {
  line1 = line(start = [var 0mm, var 0mm], end = [var 0mm, var 40mm])
  line2 = line(start = [var 0mm, var 40mm], end = [var 40mm, var 40mm])
  coincident([line1.end, line2.start])
  line3 = line(start = [var 40mm, var 40mm], end = [var 40mm, var 0mm])
  coincident([line2.end, line3.start])
  line4 = line(start = [var 40mm, var 0mm], end = [var 0mm, var 0mm])
  coincident([line3.end, line4.start])
  vertical(line1)
  horizontal(line2)
  vertical(line3)
  equalLength([line4, line3, line2, line1])
  distance([line4.start, line4.end]) == legThickness
}
region002 = region(segments = [legProfile.line1, legProfile.line2])
legExtrude = extrude(region002, length = legHeight)
  |> patternLinear3d(instances = 2, distance = tableWidth - legThickness, axis = X)
  |> patternLinear3d(instances = 2, distance = tableLength - legThickness, axis = Y)


Rectangle Table

Zookeeper

Zookeeper: The Conversational CAD Agent For Parametric Modeling

Automation

Automating Your Workflow

File Formats

A Practical Overview of CAD File Formats

KCL: A Programming Language for Parametric CAD

Geometry Engine

Zoo CAD Engine Overview