A simplified, parametric 3-D model of a low-poly toy cybertruck, intended for use as a game-ready asset, concept visualization, or real-time rendering demo.

// Stylized Toy Cybertruck
// A simplified, parametric 3-D model of a low-poly toy cybertruck, intended for use as a game-ready asset, concept visualization, or real-time rendering demo.
// Categories: Toys, Games, & Recreation; Art & Design; Parametric

// The model includes:
// - A chassis block forming the vehicle’s base
// - Front and rear fenders with wheel cut-outs
// - Four detachable wheels (tire + hubcap)
// - An angular cabin defined by intersecting trapezoids
// - Sloped front, rear, and side panels
// - Flat front and rear light panels
//
// All major dimensions are parameterized for quick adjustments.
// Geometry prioritizes stylized clarity and clean topology over realism,
// making it suitable for games, educational tools, or prototyping environments.
// Set units and version

@settings(defaultLengthUnit = m, kclVersion = 2.0)

// Chassis dimensions
chassisLength = 3.5 // total vehicle length
chassisWidth = 1.8 // total vehicle width
chassisHeight = 0.4 // height of main chassis block


// Wheel configuration
wheelBase = 2.3 // distance between front and rear wheels
wheelDiameter = 0.7 // outer diameter of tire
wheelWidth = chassisWidth * 0.15 // width of tire


// Fender geometry
fenderInset = 0.1 // horizontal gap between chassis and fender
fenderLength = chassisLength + fenderInset * 2 // overall fender span along length
fenderWidth = chassisWidth + fenderInset * 2 // overall fender span across width
fenderHeight = 0.35 // height of the fender block


// Elevation levels
groundClearance = 0.4 // vertical gap between ground and bottom of fender
chassisElevation = groundClearance + fenderHeight // bottom of the main chassis


// Hood and cabin
hoodLength = 0 // front hood segment length
cabinElevation = chassisElevation + chassisHeight // vertical start of cabin
cabinHeight = 0.8 // total cabin height
windPanelShift = chassisLength * 0.4 // slant of windshield
rearPanelShift = chassisLength - windPanelShift // slant of rear cabin wall
sidePanelShift = chassisWidth * 0.2 // slant of side cabin wall


// Front lights
headlightsElevation = cabinElevation
headlightsDistance = chassisWidth * 0.75
headlightsHeight = chassisHeight * 0.2
headlightsWidth = chassisWidth
lightDepth = 0.05 // extrusion depth for headlights and taillights


// Rear lights
taillightsOffset = 0
taillightsHeight = chassisHeight * 0.2
taillightsWidth = chassisWidth
taillightsElevation = cabinElevation
taillightsDistance = chassisWidth - (taillightsOffset * 2) - taillightsWidth
taillightsSize = chassisHeight * 0.8

// Fenders
// Protective side covers that house the wheels.
// Positioned slightly wider than the chassis to suggest ruggedness.
fenderProfile = sketch(on = XZ) {
  line1 = line(start = [var 0m, var 0m], end = [var 1m, var 0m])
  line2 = line(start = [var 1m, var 0m], end = [var 1m, var 1m])
  line3 = line(start = [var 1m, var 1m], end = [var 0m, var 1m])
  line4 = line(start = [var 0m, var 1m], end = [var 0m, var 0m])

  coincident([line1.end, line2.start])
  coincident([line2.end, line3.start])
  coincident([line3.end, line4.start])
  coincident([line4.end, line1.start])

  horizontal(line1)
  vertical(line2)
  horizontal(line3)
  vertical(line4)

  horizontalDistance([line1.start, ORIGIN]) == fenderLength / 2
  verticalDistance([ORIGIN, line1.start]) == groundClearance
  horizontalDistance([line1.start, line1.end]) == fenderLength
  verticalDistance([line1.start, line4.start]) == fenderHeight
}

fenderRegion = region(segments = [fenderProfile.line1])

fenderBody = extrude(fenderRegion, length = -chassisWidth - (fenderInset * 2), symmetric = true)
  |> appearance(%, color = "#e0e0e0")
hide(fenderProfile)

// Wheel Cutouts
// Hexagonal recesses subtracted from the fenders to make space for the wheels.
wheelCutoutSketch = sketch(on = XZ) {
  circle1 = circle(start = [var 0.5m, var 0.35m], center = [var 0m, var 0.35m], construction = true)

  line1 = line(start = [var -0.5m, var 0.35m], end = [var -0.25m, var 0.8m])
  line2 = line(start = [var -0.25m, var 0.8m], end = [var 0.25m, var 0.8m])
  coincident([line1.end, line2.start])

  line3 = line(start = [var 0.25m, var 0.8m], end = [var 0.5m, var 0.35m])
  coincident([line2.end, line3.start])
  coincident([line3.end, circle1.start])

  line4 = line(start = [var 0.5m, var 0.35m], end = [var 0.25m, var -0.1m])
  coincident([line4.start, line3.end])

  line5 = line(start = [var 0.25m, var -0.1m], end = [var -0.25m, var -0.1m])
  coincident([line4.end, line5.start])

  line6 = line(start = [var -0.25m, var -0.1m], end = [var -0.5m, var 0.35m])
  coincident([line5.end, line6.start])
  coincident([line6.end, line1.start])

  coincident([line6.end, circle1])
  coincident([line2.start, circle1])
  coincident([line3.start, circle1])
  coincident([line5.start, circle1])
  coincident([line6.start, circle1])

  equalLength([
    line5,
    line6,
    line1,
    line2,
    line3,
    line4
  ])

  line7 = line(start = [var 0m, var 0.35m], end = [var 0.5m, var 0.35m], construction = true)
  coincident([line7.start, circle1.center])
  coincident([line7.end, line4.start])
  horizontal(line7)

  horizontalDistance([ORIGIN, line7.start]) == 0m
  verticalDistance([ORIGIN, line7.start]) == wheelDiameter / 2
  horizontalDistance([line7.start, line7.end]) == wheelDiameter * 0.75
}

cutOutProfile = region(segments = [wheelCutoutSketch.line1])
cutOutVoid = extrude(cutOutProfile, length = wheelWidth * 3, symmetric = true)
hide(wheelCutoutSketch)

frontLeftCutout = clone(cutOutVoid)
  |> translate(
       x = -wheelBase / 2,
       y = -fenderWidth / 2,
       z = 0,
       global = false,
     )
rearLeftCutout = clone(cutOutVoid)
  |> translate(
       x = wheelBase / 2,
       y = -fenderWidth / 2,
       z = 0,
       global = false,
     )
frontRightCutout = clone(cutOutVoid)
  |> translate(
       x = -wheelBase / 2,
       y = fenderWidth / 2,
       z = 0,
       global = false,
     )
rearRightCutout = cutOutVoid
  |> translate(
       x = wheelBase / 2,
       y = fenderWidth / 2,
       z = 0,
       global = false,
     )

fenderWithCutouts = subtract(
  fenderBody,
  tools = [
    frontLeftCutout,
    rearLeftCutout,
    frontRightCutout,
    rearRightCutout
  ],
)
  |> appearance(%, color = "#1a1a1a")

// Chassis
// The main structural body of the vehicle, sitting above the fenders.
// Defines the base frame on which the cabin and roof are mounted.
chassisProfile = sketch(on = XZ) {
  line1 = line(start = [var 0m, var 0m], end = [var 1m, var 0m])
  line2 = line(start = [var 1m, var 0m], end = [var 1m, var 1m])
  line3 = line(start = [var 1m, var 1m], end = [var 0m, var 1m])
  line4 = line(start = [var 0m, var 1m], end = [var 0m, var 0m])

  coincident([line1.end, line2.start])
  coincident([line2.end, line3.start])
  coincident([line3.end, line4.start])
  coincident([line4.end, line1.start])

  horizontal(line1)
  vertical(line2)
  horizontal(line3)
  vertical(line4)

  horizontalDistance([line1.start, ORIGIN]) == chassisLength / 2
  verticalDistance([ORIGIN, line1.start]) == chassisElevation
  horizontalDistance([line1.start, line1.end]) == chassisLength
  verticalDistance([line1.start, line4.start]) == chassisHeight
}

chassisRegion = region(segments = [chassisProfile.line1])

chassis = extrude(chassisRegion, length = -chassisWidth, symmetric = true)
  |> appearance(%, color = "#757575") // gray body
hide(chassisProfile)

// Cabin (angular upper body)
// Defined by intersecting sloped front, back, and side profiles.
// Emulates the faceted, wedge-like shape of the Cybertruck.
cabinSideProfile = sketch(on = XZ) {
  line1 = line(start = [var -1.75m, var 1.15m], end = [var -0.35m, var 1.95m])
  line2 = line(start = [var -0.35m, var 1.95m], end = [var 1.75m, var 1.15m])
  line3 = line(start = [var 1.75m, var 1.15m], end = [var -1.75m, var 1.15m])

  coincident([line1.end, line2.start])
  coincident([line2.end, line3.start])
  coincident([line3.end, line1.start])

  horizontal(line3)
  horizontalDistance([line1.start, ORIGIN]) == chassisLength / 2
  verticalDistance([ORIGIN, line1.start]) == cabinElevation
  horizontalDistance([line1.start, line1.end]) == windPanelShift
  verticalDistance([line1.start, line1.end]) == cabinHeight
  horizontalDistance([line2.start, line2.end]) == rearPanelShift
  verticalDistance([line2.end, line2.start]) == cabinHeight
}

cabinSideRegion = region(segments = [
  cabinSideProfile.line1,
  cabinSideProfile.line2,
  cabinSideProfile.line3
])
cabinSideBody = extrude(cabinSideRegion, length = -chassisWidth, symmetric = true)
hide(cabinSideProfile)

cabinFrontProfile = sketch(on = YZ) {
  line1 = line(start = [var -0.9m, var 1.15m], end = [var -0.54m, var 1.95m])
  line2 = line(start = [var -0.54m, var 1.95m], end = [var 0.54m, var 1.95m])
  line3 = line(start = [var 0.54m, var 1.95m], end = [var 0.9m, var 1.15m])
  line4 = line(start = [var 0.9m, var 1.15m], end = [var -0.9m, var 1.15m])

  coincident([line1.end, line2.start])
  coincident([line2.end, line3.start])
  coincident([line3.end, line4.start])
  coincident([line4.end, line1.start])

  horizontal(line2)
  horizontal(line4)
  horizontalDistance([line1.start, ORIGIN]) == chassisWidth / 2
  verticalDistance([ORIGIN, line1.start]) == cabinElevation
  horizontalDistance([line1.start, line1.end]) == sidePanelShift
  verticalDistance([line1.start, line1.end]) == cabinHeight
  horizontalDistance([line2.start, line2.end]) == chassisWidth - (sidePanelShift * 2)
  horizontalDistance([line3.start, line3.end]) == sidePanelShift
  verticalDistance([line3.end, line3.start]) == cabinHeight
}

cabinFrontRegion = region(segments = [cabinFrontProfile.line1])
cabinFrontBody = extrude(cabinFrontRegion, length = chassisLength * 1.1, symmetric = true)
hide(cabinFrontProfile)

cabinBody = intersect([cabinSideBody, cabinFrontBody])
  |> appearance(%, color = "#9ce8f2")

// Wheels
// Cylindrical wheels with a central hubcap detail.
// Created as separate parts and positioned under the fender cutouts.
wheelSketch = sketch(on = XZ) {
  circle1 = circle(start = [var 0.32m, var 0.21m], center = [var -0.01m, var 0.35m])
  circle2 = circle(start = [var 0.18m, var 0.45m], center = [var -0.01m, var 0.35m])

  coincident([circle2.center, circle1.center])

  line1 = line(start = [var 0m, var 0m], end = [var -0.01m, var 0.35m], construction = true)
  coincident([line1.end, circle2.center])

  horizontalDistance([ORIGIN, line1.start]) == 0m
  verticalDistance([ORIGIN, line1.start]) == 0m
  horizontalDistance([line1.start, line1.end]) == 0m
  verticalDistance([line1.start, line1.end]) == wheelDiameter / 2
  horizontalDistance([circle2.center, circle2.start]) == wheelDiameter * 0.25
  verticalDistance([circle2.center, circle2.start]) == 0m
  horizontalDistance([circle1.center, circle1.start]) == wheelDiameter / 2
  verticalDistance([circle1.center, circle1.start]) == 0m
}

wheelProfile = region(segments = [wheelSketch.circle1])
diskProfile = region(segments = [wheelSketch.circle2])
wheelTireBody = extrude(wheelProfile, length = -wheelWidth)
  |> appearance(%, color = "#141414")
diskBody = extrude(diskProfile, length = -wheelWidth)
  |> appearance(%, color = "#d1d1d1")
hide(wheelSketch)

wheelFrontLeft = clone([wheelTireBody, diskBody])
  |> translate(
       x = -wheelBase / 2,
       y = -fenderWidth / 2,
       z = 0,
       global = false,
     )
wheelRearLeft = clone([wheelTireBody, diskBody])
  |> translate(
       x = wheelBase / 2,
       y = -fenderWidth / 2,
       z = 0,
       global = false,
     )
wheelFrontRight = clone([wheelTireBody, diskBody])
  |> rotate(
       %,
       roll = 0,
       pitch = 0,
       yaw = 180,
       global = false,
     )
  |> translate(
       x = wheelBase / 2,
       y = -fenderWidth / 2,
       z = 0,
       global = false,
     )
wheelRearRight = [wheelTireBody, diskBody]
  |> rotate(
       %,
       roll = 0,
       pitch = 0,
       yaw = 180,
       global = false,
     )
  |> translate(
       x = -wheelBase / 2,
       y = -fenderWidth / 2,
       z = 0,
       global = false,
     )

// Headlights
// Two circular front lights mounted on the front face of the chassis.
headlightsPlane = offsetPlane(YZ, offset = -chassisLength / 2)
headlightsSketch = sketch(on = headlightsPlane) {
  line1 = line(start = [var 0m, var 0m], end = [var 1m, var 0m])
  line2 = line(start = [var 1m, var 0m], end = [var 1m, var 1m])
  line3 = line(start = [var 1m, var 1m], end = [var 0m, var 1m])
  line4 = line(start = [var 0m, var 1m], end = [var 0m, var 0m])

  coincident([line1.end, line2.start])
  coincident([line2.end, line3.start])
  coincident([line3.end, line4.start])
  coincident([line4.end, line1.start])

  horizontal(line1)
  vertical(line2)
  horizontal(line3)
  vertical(line4)

  horizontalDistance([line1.start, ORIGIN]) == headlightsWidth / 2
  verticalDistance([ORIGIN, line1.start]) == headlightsElevation - headlightsHeight
  horizontalDistance([line1.start, line1.end]) == headlightsWidth
  verticalDistance([line1.start, line4.start]) == headlightsHeight
}

headlightsProfile = region(segments = [headlightsSketch.line1])
headlightsBody = extrude(headlightsProfile, length = -lightDepth)
  |> appearance(%, color = "#ededed")
hide(headlightsSketch)

// Taillights
// Two rectangular rear lights mounted on the back face of the chassis.
taillightsPlane = offsetPlane(YZ, offset = chassisLength / 2)
taillightsSketch = sketch(on = taillightsPlane) {
  line1 = line(start = [var 0m, var 0m], end = [var 1m, var 0m])
  line2 = line(start = [var 1m, var 0m], end = [var 1m, var 1m])
  line3 = line(start = [var 1m, var 1m], end = [var 0m, var 1m])
  line4 = line(start = [var 0m, var 1m], end = [var 0m, var 0m])

  coincident([line1.end, line2.start])
  coincident([line2.end, line3.start])
  coincident([line3.end, line4.start])
  coincident([line4.end, line1.start])

  horizontal(line1)
  vertical(line2)
  horizontal(line3)
  vertical(line4)

  horizontalDistance([line1.start, ORIGIN]) == taillightsWidth / 2
  verticalDistance([ORIGIN, line1.start]) == taillightsElevation - taillightsHeight
  horizontalDistance([line1.start, line1.end]) == taillightsWidth
  verticalDistance([line1.start, line4.start]) == taillightsHeight
}

taillightsProfile = region(segments = [taillightsSketch.line1])
taillightsBody = extrude(taillightsProfile, length = lightDepth)
  |> appearance(%, color = "#ff0000")
hide(taillightsSketch)


Stylized Toy Cybertruck

Zookeeper

Zookeeper: The Conversational CAD Agent For Parametric Modeling

Automation

Automating Your Workflow

File Formats

A Practical Overview of CAD File Formats

KCL: A Programming Language for Parametric CAD

Geometry Engine

Zoo CAD Engine Overview