A simplified, parametric 3-D model of a small toy car intended for use as a low-poly prop in real-time engines, visualization scenes, or rapid prototyping.

// Stylized Toy Car
// A simplified, parametric 3-D model of a small toy car intended for use as a low-poly prop in real-time engines, visualization scenes, or rapid prototyping.
// Categories: Toys, Games, & Recreation; Art & Design; Parametric

// The model includes:
// - A chassis block forming the vehicle’s base
// - Front and rear fenders with wheel cut-outs
// - Four detachable wheels (tire + hubcap)
// - A cabin with sloped windshield and rear panel
// - A thin roof slab
// - Circular headlights and rectangular taillights
//
// All major dimensions are parameterized for quick adjustments.
// Geometry prioritizes clarity and clean topology over realism, making it ideal
// for game assets, placeholder art, or visual-scripting demos.

// Set units and version
@settings(defaultLengthUnit = m, kclVersion = 2.0)

// Chassis dimensions
chassisLength = 3.5 // total vehicle length
chassisWidth = 1.8 // total vehicle width
chassisHeight = 0.4 // height of main chassis block


// Wheel configuration
wheelBase = 2.3 // distance between front and rear wheels
wheelDiameter = 0.7 // outer diameter of tire
wheelInnerDiameter = wheelDiameter * 0.5
wheelWidth = chassisWidth * 0.15 // width of tire


// Fender geometry
fenderInset = 0.1 // horizontal gap between chassis and fender
fenderLength = chassisLength + fenderInset * 2 // overall fender span along length
fenderWidth = chassisWidth + fenderInset * 2 // overall fender span across width
fenderHeight = 0.35 // height of the fender block


// Elevation levels
groundClearance = 0.4 // vertical gap between ground and bottom of fender
chassisElevation = groundClearance + fenderHeight // bottom of the main chassis


// Hood and cabin
hoodLength = chassisLength * 0.22 // front hood segment length
cabinElevation = chassisElevation + chassisHeight // vertical start of cabin
cabinHeight = 0.8 // total cabin height
cabinLength = chassisLength * 0.4 // cabin segment along the length
windPanelShift = 0.5 // slant of windshield
rearPanelShift = 0.3 // slant of rear cabin wall


// Front lights
headlightsElevation = chassisElevation + chassisHeight / 2
headlightsDistance = chassisWidth * 0.75
headlightsSize = chassisHeight * 0.8
lightDepth = 0.05 // extrusion depth for headlights and taillights


// Rear lights
taillightsOffset = chassisHeight * 0.2
taillightsHeight = chassisHeight - (taillightsOffset * 2)
taillightsWidth = taillightsHeight * 1.5
taillightsElevation = chassisElevation + taillightsOffset
taillightsDistance = chassisWidth - (taillightsOffset * 2) - taillightsWidth
taillightsSize = chassisHeight * 0.8

// Roof
roofElevation = cabinElevation + cabinHeight // roof base height
roofHeight = 0.1 // thickness of the roof block


// Reference planes
// chassisPlane = offsetPlane(XZ, offset = chassisWidth / 2) // profile plane for chassis and cabin
// fenderPlane = offsetPlane(XZ, offset = chassisWidth / 2 + fenderInset) // profile plane for outer fenders

// Fenders
// Protective side covers that house the wheels.
// Positioned slightly wider than the chassis to suggest ruggedness.
fenderProfile = sketch(on = XZ) {
  line1 = line(start = [var 0m, var 0m], end = [var 1m, var 0m])
  line2 = line(start = [var 1m, var 0m], end = [var 1m, var 1m])
  line3 = line(start = [var 1m, var 1m], end = [var 0m, var 1m])
  line4 = line(start = [var 0m, var 1m], end = [var 0m, var 0m])

  coincident([line1.end, line2.start])
  coincident([line2.end, line3.start])
  coincident([line3.end, line4.start])
  coincident([line4.end, line1.start])

  horizontal(line1)
  vertical(line2)
  horizontal(line3)
  vertical(line4)

  fixed([
    line1.start,
    [-fenderLength / 2, groundClearance]
  ])
  horizontalDistance([line1.start, line1.end]) == fenderLength
  verticalDistance([line1.start, line4.start]) == fenderHeight
}

fenderRegion = region(segments = [fenderProfile.line1])

fenderBody = extrude(fenderRegion, length = -chassisWidth - (fenderInset * 2), symmetric = true)
  |> appearance(%, color = "#e0e0e0")
hide(fenderProfile)

// Wheel Cutouts
// Hexagonal recesses subtracted from the fenders to make space for the wheels.


wheelCutoutSketch = sketch(on = XZ) {
  circle1 = circle(start = [var 0.5m, var 0.35m], center = [var 0m, var 0.35m], construction = true)

  line1 = line(start = [var -0.5m, var 0.35m], end = [var -0.25m, var 0.8m])
  line2 = line(start = [var -0.25m, var 0.8m], end = [var 0.25m, var 0.8m])
  coincident([line1.end, line2.start])

  line3 = line(start = [var 0.25m, var 0.8m], end = [var 0.5m, var 0.35m])
  coincident([line2.end, line3.start])
  coincident([line3.end, circle1.start])

  line4 = line(start = [var 0.5m, var 0.35m], end = [var 0.25m, var -0.1m])
  coincident([line4.start, line3.end])

  line5 = line(start = [var 0.25m, var -0.1m], end = [var -0.25m, var -0.1m])
  coincident([line4.end, line5.start])

  line6 = line(start = [var -0.25m, var -0.1m], end = [var -0.5m, var 0.35m])
  coincident([line5.end, line6.start])
  coincident([line6.end, line1.start])

  coincident([line6.end, circle1])
  coincident([line2.start, circle1])
  coincident([line3.start, circle1])
  coincident([line5.start, circle1])
  coincident([line6.start, circle1])

  equalLength([
    line5,
    line6,
    line1,
    line2,
    line3,
    line4
  ])

  line7 = line(start = [var 0m, var 0.35m], end = [var 0.5m, var 0.35m], construction = true)
  coincident([line7.start, circle1.center])
  coincident([line7.end, line4.start])
  horizontal(line7)

  fixed([circle1.center, [0, wheelDiameter / 2]])
  horizontalDistance([line7.start, line7.end]) == wheelDiameter * 0.75
}
cutOutProfile = region(segments = [wheelCutoutSketch.line1])
cutOutVoid = extrude(cutOutProfile, length = wheelWidth * 3, symmetric = true)
hide(wheelCutoutSketch)

// Place cut-outs


frontLeftCutout = cutOutVoid
  |> translate(
       x = -wheelBase / 2,
       y = -fenderWidth / 2,
       z = 0,
       global = false,
     )

frontCutouts = patternLinear3d(
  frontLeftCutout,
  instances = 2,
  distance = fenderWidth,
  axis = Y,
)

frontAndRearCutouts = patternLinear3d(
  frontCutouts,
  instances = 2,
  distance = wheelBase,
  axis = X,
)

fenderBodyWithWheelCutouts = subtract(fenderBody, tools = frontAndRearCutouts)
  |> appearance(%, color = "#e3e3e3")

// Chassis
// The main structural body of the vehicle, sitting above the fenders.
// Defines the base frame on which the cabin and roof are mounted.
chassisProfile = sketch(on = XZ) {
  line1 = line(start = [var 0m, var 0m], end = [var 1m, var 0m])
  line2 = line(start = [var 1m, var 0m], end = [var 1m, var 1m])
  line3 = line(start = [var 1m, var 1m], end = [var 0m, var 1m])
  line4 = line(start = [var 0m, var 1m], end = [var 0m, var 0m])
  coincident([line1.end, line2.start])
  coincident([line2.end, line3.start])
  coincident([line3.end, line4.start])
  coincident([line4.end, line1.start])
  horizontal(line1)
  vertical(line2)
  horizontal(line3)
  vertical(line4)
  fixed([
    line1.start,
    [-chassisLength / 2, chassisElevation]
  ])
  horizontalDistance([line1.start, line1.end]) == chassisLength
  verticalDistance([line1.start, line4.start]) == chassisHeight
}

chassisRegion = region(segments = [chassisProfile.line1])
chassis = extrude(chassisRegion, length = -chassisWidth, symmetric = true)
  |> appearance(%, color = "#1aff1d") // bright green body
hide(chassisProfile)

// Cabin (driver/passenger area)
// Enclosed compartment where the driver and passenger sit.
// Has a sloped windshield and back for a stylized look.
cabinSideProfile = sketch(on = XZ) {
  line1 = line(start = [var 0m, var 0m], end = [var 1m, var 1m])
  line2 = line(start = [var 1m, var 1m], end = [var 2m, var 1m])
  line3 = line(start = [var 2m, var 1m], end = [var 3m, var 0m])
  line4 = line(start = [var 3m, var 0m], end = [var 0m, var 0m])
  coincident([line1.end, line2.start])
  coincident([line2.end, line3.start])
  coincident([line3.end, line4.start])
  coincident([line4.end, line1.start])
  horizontal(line2)
  horizontal(line4)
  fixed([
    line1.start,
    [
      -chassisLength / 2 + hoodLength,
      cabinElevation
    ]
  ])
  horizontalDistance([line1.start, line1.end]) == windPanelShift
  verticalDistance([line1.start, line1.end]) == cabinHeight
  horizontalDistance([line2.start, line2.end]) == cabinLength
  horizontalDistance([line3.start, line3.end]) == rearPanelShift
  verticalDistance([line3.end, line3.start]) == cabinHeight
}

cabinSideRegion = region(segments = [cabinSideProfile.line1])
cabinBody = extrude(cabinSideRegion, length = -chassisWidth, symmetric = true)
  |> appearance(%, color = "#9ce8f2")
hide(cabinSideProfile)

// Roof
// Flat rectangular panel capping the top of the cabin.
// Simplified to a thin block for a toy-like appearance.
roofProfile = sketch(on = XZ) {
  line1 = line(start = [var 0m, var 0m], end = [var 1m, var 0m])
  line2 = line(start = [var 1m, var 0m], end = [var 1m, var 1m])
  line3 = line(start = [var 1m, var 1m], end = [var 0m, var 1m])
  line4 = line(start = [var 0m, var 1m], end = [var 0m, var 0m])
  coincident([line1.end, line2.start])
  coincident([line2.end, line3.start])
  coincident([line3.end, line4.start])
  coincident([line4.end, line1.start])
  horizontal(line1)
  vertical(line2)
  horizontal(line3)
  vertical(line4)
  fixed([
    line1.start,
    [
      hoodLength + windPanelShift - (chassisLength / 2),
      roofElevation
    ]
  ])
  horizontalDistance([line1.start, line1.end]) == cabinLength
  verticalDistance([line1.start, line4.start]) == roofHeight
}

roofRegion = region(segments = [roofProfile.line1])

roof = extrude(roofRegion, length = -chassisWidth, symmetric = true)
  |> appearance(%, color = "#1aff1d") // bright green body
hide(roofProfile)

// Wheels
// Cylindrical wheels with a central hubcap detail.
// Created as separate parts and positioned under the fender cutouts.
wheelSketch = sketch(on = XZ) {
  circle1 = circle(start = [var 0.32m, var 0.21m], center = [var -0.01m, var 0.35m])
  circle2 = circle(start = [var 0.18m, var 0.45m], center = [var -0.01m, var 0.35m])
  coincident([circle2.center, circle1.center])
  line1 = line(start = [var 0m, var 0m], end = [var -0.01m, var 0.35m], construction = true)
  coincident([line1.start, ORIGIN])
  coincident([line1.end, circle2.center])
  verticalDistance([line1.start, line1.end]) == wheelDiameter / 2
  diameter(circle2) == wheelInnerDiameter
  diameter(circle1) == wheelDiameter
}
wheelProfile = region(segments = [wheelSketch.circle1])
diskProfile = region(segments = [wheelSketch.circle2])
wheelTireBody = extrude(wheelProfile, length = -wheelWidth)
  |> appearance(%, color = "#141414")
diskBody = extrude(diskProfile, length = -wheelWidth)
  |> appearance(%, color = "#d1d1d1")
hide(wheelSketch)

wheelFrontLeft = clone([wheelTireBody, diskBody])
  |> translate(
       x = -wheelBase / 2,
       y = -fenderWidth / 2,
       z = 0,
       global = false,
     )
wheelRearLeft = clone([wheelTireBody, diskBody])
  |> translate(
       x = wheelBase / 2,
       y = -fenderWidth / 2,
       z = 0,
       global = false,
     )
wheelFrontRight = clone([wheelTireBody, diskBody])
  |> rotate(
       %,
       roll = 0,
       pitch = 0,
       yaw = 180,
       global = false,
     )
  |> translate(
       x = wheelBase / 2,
       y = -fenderWidth / 2,
       z = 0,
       global = false,
     )
wheelRearRight = [wheelTireBody, diskBody]
  |> rotate(
       %,
       roll = 0,
       pitch = 0,
       yaw = 180,
       global = false,
     )
  |> translate(
       x = -wheelBase / 2,
       y = -fenderWidth / 2,
       z = 0,
       global = false,
     )

// Headlights
// Two circular front lights mounted on the front face of the chassis.
headlightsPlane = offsetPlane(YZ, offset = -chassisLength / 2)
headlightsSketch = sketch(on = headlightsPlane) {
  circle1 = circle(start = [var 0.2m, var 0.95m], center = [var 0.1m, var 0.95m])

  fixed([
    circle1.center,
    [
      headlightsDistance / 2,
      headlightsElevation
    ]
  ])
  horizontalDistance([circle1.center, circle1.start]) == headlightsSize / 2
  verticalDistance([circle1.center, circle1.start]) == 0
}
headlightsProfile = region(segments = [headlightsSketch.circle1])
  |> patternLinear2d(
       %,
       instances = 2,
       distance = headlightsDistance,
       axis = [-1, 0],
     )
headlightsBody = extrude(headlightsProfile, length = -lightDepth)
  |> appearance(%, color = "#ffffff")
hide(headlightsSketch)

// Taillights
// Two rectangular rear lights mounted on the back face of the chassis.
taillightsPlane = offsetPlane(YZ, offset = chassisLength / 2)
taillightsSketch = sketch(on = taillightsPlane) {
  line1 = line(start = [var 0m, var 0m], end = [var 1m, var 0m])
  line2 = line(start = [var 1m, var 0m], end = [var 1m, var 1m])
  line3 = line(start = [var 1m, var 1m], end = [var 0m, var 1m])
  line4 = line(start = [var 0m, var 1m], end = [var 0m, var 0m])

  coincident([line1.end, line2.start])
  coincident([line2.end, line3.start])
  coincident([line3.end, line4.start])
  coincident([line4.end, line1.start])

  horizontal(line1)
  vertical(line2)
  horizontal(line3)
  vertical(line4)

  fixed([
    line1.start,
    [
      -chassisWidth / 2 + taillightsOffset,
      taillightsElevation
    ]
  ])
  horizontalDistance([line1.start, line1.end]) == taillightsWidth
  verticalDistance([line1.start, line4.start]) == taillightsHeight
}
taillightsProfile = region(segments = [taillightsSketch.line1])
  |> patternLinear2d(
       %,
       instances = 2,
       distance = taillightsDistance,
       axis = [1, 0],
     )
taillightsBody = extrude(taillightsProfile, length = lightDepth)
  |> appearance(%, color = "#ff0000")
hide(taillightsSketch)


Stylized Toy Car

Zookeeper

Zookeeper: The Conversational CAD Agent For Parametric Modeling

Automation

Automating Your Workflow

File Formats

A Practical Overview of CAD File Formats

KCL: A Programming Language for Parametric CAD

Geometry Engine

Zoo CAD Engine Overview