3-D-printable U-shaped guard that slides onto a desk edge and raises a vertical wall to keep pens, phones, cables, etc. from slipping off the tabletop.

// Desk-Edge Stopper
// 3-D-printable U-shaped guard that slides onto a desk edge and raises a vertical wall to keep pens, phones, cables, etc. from slipping off the tabletop.
// Categories: Maker

@settings(defaultLengthUnit = mm)

// PROFILE PARAMETERS
// Edit only the variables in this block
// Everything else updates automatically

// Overall length of the guard measured along the desk edge (X direction)
guardLengthAlongDesk = 200

// Define U-Profile
// Depth of the U-profile. Defines how far the stopper wraps over the desk edge. Measured from front to back. Deeper depth increases grip and stability
uProfileDepthInside = 30
// Inner width of the U-profile. Must match the thickness of the desk, plus a small tolerance (~0.5 mm) to slide on snugly without being too tight.
uProfileWidthInside = 20.5
// Height of the vertical wall that blocks objects from falling. This part rises above the desk surface. Typically between 20-50 mm depending on what you want to stop.
stopWallHeight = 20
// A uniform wall thickness is used across all parts for modeling simplicity; for 3D printing, a relatively thick value (around 1/4 to 1/6 of the profile size, min 5mm) ensures strength and reliable fabrication.
materialThickness = 5

// Total vertical height of the guard from base to top of the stopper wall
totalGuardHeight = stopWallHeight + uProfileWidthInside + materialThickness * 2
// Total front-to-back depth of the guard, including wall thickness, measured from the desk-facing surface to the outermost back face
totalGuardDepth = uProfileDepthInside + materialThickness

// HOLE PARAMETERS
// Include three screw holes: one centered for general mounting, and one near each end for desks with side-positioned predrilled holes. Covers common installation cases without overcomplicating the layout.
holeCount = 3
// Distance from desk edge to screw hole center; here set to 13 mm. Best positioned near the middle of the upper U-profile surface to reduce risk of cracking.
holeOffsetFromTheTableEdge = 13
// Convert to offset relative to U-profile geometry
holeOffsetFromTheUprofileEdge = uProfileDepthInside - holeOffsetFromTheTableEdge
// Diameter and radius of each hole
holeDiameter = 4
holeRadius = holeDiameter / 2
// Offset to the profile ends for outermost holes. Should be around one-sixth of the length.
holeOffsetFromGuardEdge = guardLengthAlongDesk / 6
// The spacing between the first and last screw holes equals the total guard length minus two side offsets.
holeSpan = guardLengthAlongDesk - (holeOffsetFromGuardEdge * 2)
// Spacing between holes is calculated by dividing the span (first to last hole) by the number of gaps between them, which is one less than the total hole count.
holeSpacing = holeSpan / (holeCount - 1)

// ───────────
// 3D GEOMETRY
// ───────────
// Begin with a 2D sketch of the cross-section. The internal shape comes first, since it must adapt precisely to desk thickness, the rest builds around it. This keeps the model parametric and resilient to design changes.
guardProfile = sketch(on = YZ) {
  line1 = line(start = [var 0mm, var 0mm], end = [var 31mm, var 1mm])
  line2 = line(start = [var 31mm, var -1mm], end = [var 30mm, var 21mm])
  coincident([line1.end, line2.start])

  line3 = line(start = [var 29mm, var 20mm], end = [var -1mm, var 21mm])
  coincident([line2.end, line3.start])

  line4 = line(start = [var 1mm, var 21mm], end = [var -1mm, var 27mm])
  coincident([line3.end, line4.start])

  line5 = line(start = [var -1mm, var 26mm], end = [var 29mm, var 25mm])
  coincident([line4.end, line5.start])

  line6 = line(start = [var 31mm, var 26mm], end = [var 29mm, var 46mm])
  coincident([line5.end, line6.start])

  line7 = line(start = [var 31mm, var 46mm], end = [var 36mm, var 45mm])
  coincident([line6.end, line7.start])

  line8 = line(start = [var 34mm, var 45mm], end = [var 36mm, var -6mm])
  coincident([line7.end, line8.start])

  line9 = line(start = [var 34mm, var -6mm], end = [var 1mm, var -5mm])
  coincident([line8.end, line9.start])

  line10 = line(start = [var -1mm, var -5mm], end = [var 0mm, var 0mm])
  coincident([line9.end, line10.start])
  coincident([line10.end, line1.start])

  horizontal(line1)
  vertical(line2)
  horizontal(line3)
  vertical(line4)
  horizontal(line5)
  vertical(line6)
  horizontal(line7)
  vertical(line8)
  horizontal(line9)
  vertical(line10)

  coincident([line1.start, ORIGIN])
  coincident([
    line2.end,
    [
      uProfileDepthInside,
      uProfileWidthInside
    ]
  ])

  verticalDistance([line4.start, line4.end]) == materialThickness
  verticalDistance([line6.start, line6.end]) == stopWallHeight
  equalLength([line1, line3, line5])
  equalLength([line4, line7, line10])
}
guardRegion = region(segments = [guardProfile.line1, guardProfile.line2])
hiddenGuardProfile = hide(guardProfile)
guardBody = extrude(guardRegion, length = guardLengthAlongDesk)

// MOUNTING METHOD
// This model is specifically designed for screw mounting. It includes three holes, one in the center and one near each end, positioned on the top face of the U-profile to align with existing holes on the upper side of the desk.
// HOLE GEOMETRY
// holes
holeProfile01 = sketch(on = XY) {
  circle1 = circle(start = [var 2mm, var 0mm], center = [var 0mm, var 0mm])
  radiusGuide = line(start = [var 0mm, var 0mm], end = [var 2mm, var 0mm], construction = true)

  coincident([circle1.center, ORIGIN])
  coincident([radiusGuide.start, circle1.center])
  coincident([radiusGuide.end, circle1.start])

  horizontal(radiusGuide)
  horizontalDistance([radiusGuide.start, radiusGuide.end]) == holeRadius
}
holeRegion01 = region(segments = [holeProfile01.circle1])
hiddenHoleProfile01 = hide(holeProfile01)
baseHoleBody = extrude(holeRegion01, length = -materialThickness)
  |> translate(
       x = holeOffsetFromGuardEdge,
       y = holeOffsetFromTheUprofileEdge,
       z = uProfileWidthInside + materialThickness,
       global = true,
     )
holeBody02 = clone(baseHoleBody)
  |> translate(x = holeSpacing, global = true)
holeBody03 = clone(baseHoleBody)
  |> translate(x = holeSpacing * 2, global = true)
guardBodyWithHoles = subtract([guardBody], tools = [baseHoleBody, holeBody02, holeBody03])


Desk-Edge Stopper

Zookeeper

Zookeeper: The Conversational CAD Agent For Parametric Modeling

Automation

Automating Your Workflow

File Formats

A Practical Overview of CAD File Formats

KCL: A Programming Language for Parametric CAD

Geometry Engine

Zoo CAD Engine Overview